Overview

//PR Review Time 
GithubPullRequests
| where updated between (ago(7d)  .. now())
| where isnotnull(mergedAt)
| project repo, url, ['title'], user, prReviewTime = createdAt-mergedAt

GithubPullRequests
| where createdAt between (_startTime .. _endTime)
| where user != "dependabot[bot]"
| summarize prs = count() by bin_at(createdAt, 7d,now())

// PR's closed per day in the last 30 days
GithubPullRequests
| where closedAt > ago(30d)
| summarize count() by bin(closedAt, 1d)
| render columnchart

User views

//Pull Requests count by user per week
GithubPullRequests
| where createdAt > ago(100d)
| where user != "dependabot[bot]"
| summarize count() by user, bin_at(createdAt, 7d, now())
| render timechart

//Pull Requests count by user 
GithubPullRequests
| where createdAt > ago(100d)
| where user != "dependabot[bot]"
| summarize count() by user

//Files changed by user
GithubPullRequests
| where createdAt > ago(100d)
| where user != "dependabot[bot]"
| project url, ['title'], user , changedFiles
| summarize sum(changedFiles) by user

//PR review time 50th and 90th percentile by user
GithubPullRequests
| where isnotnull(mergedAt)
| extend  openTime = closedAt - createdAt
| summarize percentiles(openTime, 50, 90) by user 
| project user, percentile_openTime_50, percentile_openTime_90
| sort by percentile_openTime_90 desc

//Comments size by user
let Comments =
GithubPullRequestReviewComments
| where createdAt between (ago(90d) .. now()) 
| summarize comments = sum(strlen(body)) by user;
GithubPullRequestReviews
| where submittedAt between (ago(90d) .. now()) 
| summarize reviews = sum(strlen(body)) by user
| join kind=leftouter Comments on $left.user == $right.user
| summarize sum(comments) + sum(reviews) by user

//Comments by user
let Comments =
GithubPullRequestReviewComments
| where createdAt between (ago(90d) .. now()) 
| summarize comments = count() by user;
GithubPullRequestReviews
| where submittedAt between (ago(90d) .. now()) 
| summarize reviews = count() by user
| join kind=leftouter Comments on $left.user == $right.user
| summarize sum(comments) + sum(reviews) by user

Repo views

//Pull Requests count by repo
GithubPullRequests
| summarize count() by repo